$title Grid Transportation Problem (TRNSGRID,SEQ=315)

$onText
This problem finds a least cost shipping schedule that meets
requirements at markets and supplies at factories.

The model demonstrates how to run multiple scenarios with different
demands in a parallel fashion using the GAMS Grid Facility.

Dantzig, G B, Chapter 3.3. In Linear Programming and Extensions.
Princeton University Press, Princeton, New Jersey, 1963.

Keywords: linear programming, transportation problem, scheduling, GAMS grid facility,
          scenario analysis
$offText

Set
   i 'canning plants' / seattle,  san-diego /
   j 'markets'        / new-york, chicago, topeka /;

Parameter
   a(i) 'capacity of plant i in cases'
        / seattle    350
          san-diego  600 /

   b(j) 'demand at market j in cases'
        / new-york   325
          chicago    300
          topeka     275 /;

Table d(i,j) 'distance in thousands of miles'
              new-york  chicago  topeka
   seattle         2.5      1.7     1.8
   san-diego       2.5      1.8     1.4;

Scalar f 'freight in dollars per case per thousand miles' / 90 /;

Parameter c(i,j) 'transport cost in thousands of dollars per case';
c(i,j) = f*d(i,j)/1000;

Variable
   x(i,j) 'shipment quantities in cases'
   z      'total transportation costs in thousands of dollars';

Positive Variable x;

* Demonstrate how to restrict the model index
Set ij(i,j); ij(i,j) = yes;

Equation
   cost      'define objective function with economies of scale'
   supply(i) 'observe supply limit at plant i'
   demand(j) 'satisfy demand at market j';

cost..      z =e= sum(ij(i,j), c(i,j)*x(i,j));

supply(i).. sum(j, x(i,j)) =l= a(i);

demand(j).. sum(i, x(i,j)) =g= b(j);

Model transport / all /;

$eolCom //

transport.solveLink = %solveLink.asyncGrid%;  // turn on grid option
transport.limCol    = 0;
transport.limRow    = 0;
transport.solPrint  = %solPrint.quiet%;

Set s 'scenarios' / 1*5 /;

Parameter
   dem(s,j) 'random demand'
   h(s)     'store the instance handle';

dem(s,j) = b(j)*uniform(.95,1.15); // create some random demands

loop(s,
   b(j) = dem(s,j);
   solve transport using lp minimizing z;
   h(s) = transport.handle;    // save instance handle
);

$ifThen not set ETIME_LIMIT
* jobTrace is used as an indicator that slvtest called this model
$  if not "%gams.jobTrace%" $set ETIME_LIMIT 10
$  if     "%gams.jobTrace%" $set ETIME_LIMIT INF
$endIf

Parameter
   etimeLim  'time limit for collection loop' / %ETIME_LIMIT% /
   repx(s,i,j) 'solution report'
   repy        'summary report';

repy(s,'solvestat') = na;
repy(s,'modelstat') = na;

* we use the handle parameter to indicate that the solution has been collected
repeat
   loop(s$handlecollect(h(s)),
      repx(s,i,j)         = x.l(i,j);
      repy(s,'solvestat') = transport.solveStat;
      repy(s,'modelstat') = transport.modelStat;
      repy(s,'resusd'   ) = transport.resUsd;
      repy(s,'objval')    = transport.objVal;
      display$handledelete(h(s)) 'trouble deleting handles';
      h(s) = 0;    // indicate that we have loaded the solution
   );
   display$sleep(card(h)*0.2) 'was sleeping for some time';
until card(h) = 0 or timeelapsed > etimeLim;  // wait until all models are loaded

display repx, repy;

abort.noError$[card(h)>0] 'Grid collection loop too slow', etimeLim, h;
abort$sum(s$(repy(s,'solvestat') = na),1) 'Some jobs did not return';